# $Id$
# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>

pkgbase=linux-libre-tools
_pkgname=('perf' 'cpupower')
pkgname=('perf-libre' 'cpupower-libre')
_basekernel=3.4
#_sublevel=1
#pkgver=${_basekernel}.${_sublevel}
pkgver=${_basekernel}
pkgrel=1
license=('GPL2')
arch=('i686' 'x86_64' 'mips64el')
url='http://linux-libre.fsfla.org/'
options=('!strip')
makedepends=('asciidoc' 'xmlto')
# split packages need all package dependencies set manually in makedepends
makedepends+=('python2' 'libnewt' 'elfutils' 'pciutils')
source=("http://linux-libre.fsfla.org/pub/linux-libre/releases/${_basekernel}-gnu/linux-libre-${_basekernel}-gnu.tar.xz"
        #"http://linux-libre.fsfla.org/pub/linux-libre/releases/${pkgver}-gnu/patch-${_basekernel}-gnu-${pkgver}-gnu.xz"
        'cpupower.rc'
        'cpupower.conf'
        'cpupower.service')
md5sums=('a5e128ca059cceb8b69148b41ff4ac6f'
         '73dbc931e86b3b73d6e2338dcbee81a4'
         '18d5aa9e4c6bb23bb02bf65e155e0f0e'
         '20870541e88109d2f153be3c58a277f1')

build() {
  cd "${srcdir}/linux-${_basekernel}"

  if [ "${_basekernel}" != "${pkgver}" ]; then
    patch -Np1 -i "${srcdir}/patch-${_basekernel}-gnu-${pkgver}-gnu"
  fi

  cd ${srcdir}
  msg2 'Build perf'
  pushd linux-$pkgver/tools/perf
  make \
    DESTDIR="$pkgdir/usr" \
    perfexecdir="lib/$_pkgname" \
    PYTHON=python2 \
    NO_GTK2=1 \
    PERF_VERSION=$pkgver-$pkgrel \
    all man
  popd

  msg2 'Build cpupower'
  cd linux-$pkgver/tools/power/cpupower
  # we cannot use --as-needed
  LDFLAGS=${LDFLAGS:+"$LDFLAGS,--no-as-needed"}
  make VERSION=$pkgver-$pkgrel
}

package_perf-libre() {
  pkgdesc='Linux-libre kernel performance auditing tool'
  depends=('python2' 'libnewt' 'elfutils')
  replaces=('perf')  
  conflicts=('perf')
  provides=("perf=$pkgver")

  cd linux-$pkgver/tools/perf
  make \
    DESTDIR="$pkgdir/usr" \
    perfexecdir="lib/$_pkgname" \
    PYTHON=python2 \
    NO_GTK2=1 \
    PERF_VERSION=$pkgver-$pkgrel \
    install install-man
}

package_cpupower-libre() {
  pkgdesc='Linux-libre kernel tool to examine and tune power saving related features of your processor'
  backup=('etc/conf.d/cpupower')
  depends=('pciutils')
  replaces=('cpupower')
  conflicts=('cpupower' 'cpufrequtils')
  provides=("cpupower=$pkgver")

  pushd linux-$pkgver/tools/power/cpupower
  make \
    DESTDIR="$pkgdir" \
    mandir='/usr/share/man' \
    docdir='/usr/share/doc/cpupower' \
    install install-man
  popd
  # install rc.d script
  install -D -m 755 cpupower.rc "$pkgdir/etc/rc.d/cpupower"
  install -D -m 644 cpupower.conf "$pkgdir/etc/conf.d/cpupower"
  install -D -m 644 cpupower.service "$pkgdir/usr/lib/systemd/system/cpupower.service"
}

# vim:set ts=2 sw=2 ft=sh et: