# $Id$
# Maintainer: Allan McRae <allan@archlinux.org>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>

# toolchain build order: linux-libre-api-headers->glibc->binutils->gcc->binutils->glibc

pkgname=linux-libre-api-headers
pkgver=3.1.6
_basever=3.1
pkgrel=2
pkgdesc="Kernel Libre headers sanitized for use in userspace"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnu.org/software/libc"
license=('GPL2')
provides=("linux-api-headers=${pkgver}" "kernel-headers=${pkgver}")
conflicts=('linux-api-headers' 'kernel-headers')
replaces=('linux-api-headers' 'kernel-headers')
source=("http://linux-libre.fsfla.org/pub/linux-libre/releases/${_basever}-libre/linux-${_basever}-libre.tar.xz"
        "http://linux-libre.fsfla.org/pub/linux-libre/releases/${pkgver}-libre/patch-${_basever}-libre-${pkgver}-libre.xz")
md5sums=('d73df15ab1d36fe3c102755d8f42117f'
         'cb42276bca126c676c51d02d74bf7fe7')

build() {
  cd ${srcdir}/linux-${_basever}
  [[ $pkgver != $_basever ]] && patch -Np1 -i ${srcdir}/patch-${_basever}-libre-${pkgver}-libre

  make mrproper
  make headers_check
}

package() {
  cd ${srcdir}/linux-${_basever}
  make INSTALL_HDR_PATH=${pkgdir}/usr headers_install

  # use headers from libdrm
  rm -rf ${pkgdir}/usr/include/drm
  
  # clean-up unnecessary files generated during install
  find ${pkgdir} -name .install -or -name ..install.cmd | xargs rm -f
}