# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=libretools
pkgname=(libretools librelib gitget xbs)
pkgdesc="Programs for Parabola development"
url="https://projects.parabola.nu/packages/libretools.git/"
license=('GPL3' 'GPL2')

pkgver=20150607
_libretools_commit=9c26929bb8f7279620bff5db68ee9291eef393b3
_devtools_commit=c271ab745f80167f452ee6afa1ff430c2f1523b0
md5sums=('32fab6c2c214bc1a233b55fa8a767b2b'
         'ffee2c79249bd9727826c39946934a08')

_packages_url=https://projects.parabola.nu/packages
source=($_packages_url/libretools.git/snapshot/libretools-$_libretools_commit.tar.bz2
	$_packages_url/devtools-par.git/snapshot/devtools-par-$_devtools_commit.tar.bz2)

pkgrel=4
arch=('any')
makedepends=(emacs ruby-ronn) # emacs --batch is used during the build to process text
checkdepends=(sh-roundup git)

build() {
  cd "$srcdir"
  ln -sf devtools-par-$_devtools_commit devtools-par
  cd "$srcdir/$pkgbase-$_libretools_commit"
  make
}

check() {
  cd "$srcdir/$pkgbase-$_libretools_commit"

  SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
}

package_librelib() {
  pkgdesc="The shell library portion of libretools"
  license=(GPL2)
  depends=(
    wget # `blacklist`
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-librelib DESTDIR="$pkgdir"
}

package_gitget() {
  pkgdesc="A simple to use downloader for git URLs"
  license=(GPL2)
  depends=("librelib=$pkgver" git)

  provides=("libregit=$pkgver")
  conflicts=("libregit")
  replaces=("libregit")

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-gitget DESTDIR="$pkgdir"
}

package_xbs() {
  pkgdesc='A tool for working with arbitrary ABS-like build systems'
  backup=(etc/xbs/xbs.conf
          etc/xbs/xbs-abs.conf)
  license=(GPL2)
  depends=(
    "gitget=$pkgver" # `helper-abslibre`
    "librelib=$pkgver"
    subversion # `helper-abs`
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-xbs DESTDIR="$pkgdir"
}

package_libretools() {
  backup=(etc/libretools.conf
          etc/libretools.d/chroot.conf
          etc/libretools.d/librefetch.conf)
  install=libretools.install
  conflicts=(devtools)
  conflicts=(libretools-mips64el)
  replaces=(libretools-mips64el)

  depends=(
    "librelib=$pkgver"
    "xbs=$pkgver" # `createworkdir`, `librestage`
    'pacman>=4.2.0' 'pacman<4.3.0'
    arch-install-scripts # `mkarchroot` uses `pacstrap`
    openssh # `librerelease`
    rsync # `librerelease` and `makechrootpkg.sh`
    systemd # systemd-nspawn
    tokyocabinet # `toru`
    #namcap # Namcap is currently dissabled in libremakepkg :(
    #subversion # `diff-unfree` # ignore because of xbs
    #wget # `aur` # ignore because of librelib
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools install-doc DESTDIR="$pkgdir"
}