# $Id: PKGBUILD 228005 2014-12-24 13:30:15Z jgc $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=digikam
pkgname=kipi-plugins
pkgver=4.5.0
pkgrel=4.parabola1
pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree jAlbum and SimpleViewer support"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.digikam.org/"
replaces=("${pkgname}-libre")
conflicts=("${pkgname}-libre")
makedepends=('kdepimlibs' 'libkexiv2' 'libkdcraw' 'libkipi' 'libksane' 'liblqr'
             'kdeedu-marble' 'opencv' 'boost' 'libgpod' 'qjson' 'hugin' 'libgphoto2'
             'cmake' 'automoc4' 'doxygen' 'lensfun' 'qt-gstreamer' 'imagemagick' 'eigen' 
	     'libbaloo4' 'libpgf' 'libusb-compat')
depends=('kdebase-runtime' 'kdepimlibs' 'libkdcraw' 'libkipi' 'libksane' 'libkexiv2')
optdepends=('libkgeomap: Geolocalize tool'
            'libmediawiki: MediaWiki Export plugin'
            'libkvkontakte: VKontakte.ru Exporter plugin'
            'libgpod: iPodExport plugin'
            'opencv: Remove Red Eyes plugin'
            'imagemagick: Video SlideShow plugin'
            'qt-gstreamer: Video SlideShow plugin')
options=('staticlibs')
install=kipi-plugins.install
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${pkgver}.tar.bz2"
	"libkexiv2.patch")
sha1sums=('ba735f4b7bb0437c1676141ab78ea958e46f135e'
          '1bcef459bd400a04526aac9adf39d4d0a1c3549c')

prepare() {
  cd ${srcdir}/${pkgbase}-${pkgver}
  patch -Np0 -i "${srcdir}/libkexiv2.patch"
  sed -i '\|flashexport|d
          \|jalbumexport|d
         ' extra/kipi-plugins/CMakeLists.txt
}

build() {
  mkdir build
  cd build
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DBUILD_tests=OFF \
    -DDIGIKAMSC_USE_PRIVATE_KDEGRAPHICS=OFF \
    -DDIGIKAMSC_USE_PRIVATE_SHAREDLIBS=ON
  make
}

package() {
  cd build/extra/kipi-plugins
  make DESTDIR="${pkgdir}" install

  cd ../../../build/po
  make DESTDIR="${pkgdir}" install
  # Put these in the relevant splitted packages
  rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/libkgeomap.mo
  rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/digikam.mo
  # Fix conflicts with kde-l10n-* (FS#33762)
  rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/libkipi.mo
}