# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
# Contributor (ConnochaetOS): Henry Jensen <hjensen@connochaetos.org>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: vando <facundo@esdebian.org>
# Contributor (Arch): Jakub Schmidtke <sjakub@gmail.com>
# Contributor: Figue <ffigue at gmail>
# Contributor: taro-k <taro-k@movasense_com>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com> 

_pgo=true

# We're getting this from Debian Sid
_debname=iceweasel
_debver=44.0.2
_debrel=deb1
_debrepo=http://ftp.debian.org/debian/pool/main/
debfile() { echo $@|sed -r 's@(.).*@\1/&/&@'; }

_pkgname=firefox
pkgname=iceweasel
epoch=1
pkgver=$_debver.$_debrel
pkgrel=1

pkgdesc="A libre version of Debian Iceweasel, the standalone web browser based on Mozilla Firefox."
arch=(i686 x86_64)
license=(MPL GPL LGPL)
depends=(alsa-lib dbus-glib desktop-file-utils gtk2 gtk3 hicolor-icon-theme hunspell icu=56.1 libevent libvpx=1.5.0 libxt mime-types mozilla-common nss sqlite startup-notification ttf-font)
makedepends=(autoconf2.13 diffutils gconf imagemagick imake inetutils libidl2 libpulse librsvg libxslt mesa mozilla-searchplugins pkg-config python2 quilt unzip yasm zip)
options=(!emptydirs !makeflags debug)
if $_pgo; then
  makedepends+=(xorg-server-xvfb)
  options+=(!ccache)
fi
optdepends=('networkmanager: Location detection via available WiFi networks'
            'ffmpeg: H264/AAC/MP3 decoding'
            'upower: Battery API')
url="http://packages.debian.org/sid/$pkgname"
install=$pkgname.install
replaces=("$pkgname-libre" "$_pkgname")
conflicts=("$pkgname-libre")
source=("$_debrepo/`debfile $_debname`_$_debver.orig.tar.xz"
        "$_debrepo/`debfile $_debname`_$_debver-${_debrel#deb}.debian.tar.xz"
        mozconfig
        libre.patch
        gnu_headshadow.png
        drm-free.png
        $pkgname.desktop
        $pkgname-install-dir.patch
        vendor.js
        $pkgname-fixed-loading-icon.png)
sha256sums=('adc1c9127b73bd11b282a469d499122396d63af1a4f1e8d5a9cfd46e36899834'
            '58560cf8c8632de5b943b8ca000bad8607b1a1144ad082d2cae5ef7bf1488258'
            'abc617c170b0c4d549d1995d018285e16e9a30adf5e9c116d8b4d0070758070f'
            'a28bd21522f0c7d93e9669f1fcc35309c9841d9b2332aa16b0b746ad18fc878c'
            '93e3001ce152e1d142619e215a9ef07dd429943b99d21726c25da9ceb31e31cd'
            '56eba484179c7f498076f8dc603d8795e99dce8c6ea1da9736318c59d666bff6'
            '2257dc69886bd0b72c48675a27c3a88b9cf6b598252c9e9f1c99763180684fc3'
            '3aea6676f1e53a09673b6ae219d281fc28054beb6002b09973611c02f827651d'
            'e6e43c6b481891e33dbb95849865410a2a9e77165f7de2c2057d3a8bab990aec'
            '68e3a5b47c6d175cc95b98b069a15205f027cab83af9e075818d38610feb6213')

prepare() {
  cd "$srcdir/$_pkgname-$_debver"
  mv "$srcdir/debian" .

  export QUILT_PATCHES=debian/patches
  export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
  export QUILT_DIFF_ARGS='--no-timestamps'

  quilt push -av

  # Put gnu_headshadow.png and drm-free.png in the source code
  install -m644 "$srcdir/"{gnu_headshadow,drm-free}.png \
    browser/base/content/abouthome

  # Install to /usr/lib/$pkgname
  patch -Np1 -i "$srcdir/$pkgname-install-dir.patch"

  # Patch and remove anything that's left
  patch -Np1 -i "$srcdir/libre.patch"
  sed -i 's|Adobe Flash|SWF Player|g;
         ' browser/base/content/pageinfo/permissions.js \
           browser/base/content/browser-plugins.js
  sed -i '\|["]displayName["][:] ["]Flash["]| s|Flash|SWF Player|
          \|["]displayName["][:] ["]Shockwave["]| s|Shockwave|DCR Player|
          \|["]displayName["][:] ["]QuickTime["]| s|QuickTime|MOV Player|
          \|installLinux| s|true|false|
         ' browser/base/content/browser-plugins.js

  # Load our build config, disable SafeSearch
  cp "$srcdir/mozconfig" .mozconfig

  mkdir "$srcdir/path"

  # WebRTC build tries to execute "python" and expects Python 2
  ln -s /usr/bin/python2 "$srcdir/path/python"

  # Configure script misdetects the preprocessor without an optimization level
  # https://bugs.archlinux.org/task/34644
  sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' configure

  # Fix tab loading icon (doesn't work with libpng 1.6)
  # https://bugzilla.mozilla.org/show_bug.cgi?id=841734
  cp "$srcdir/$pkgname-fixed-loading-icon.png" \
    browser/themes/linux/tabbrowser/loading.png

  # Load our searchplugins
  rm -rv browser/locales/en-US/searchplugins
  cp -av /usr/lib/mozilla/searchplugins browser/locales/en-US
}

build() {
  cd "$srcdir/$_pkgname-$_debver"

  export PATH="$srcdir/path:$PATH"
  export PYTHON="/usr/bin/python2"

  if $_pgo; then
    # Do PGO
    xvfb-run -a -s "-extension GLX -screen 0 1280x1024x24" \
      make -f client.mk build MOZ_PGO=1
  else
    make -f client.mk build
  fi
}

package() {
  cd "$srcdir/$_pkgname-$_debver"
  make -f client.mk DESTDIR="$pkgdir" INSTALL_SDK= install

  install -Dm644 ../vendor.js "$pkgdir/usr/lib/$pkgname/browser/defaults/preferences/vendor.js"

  _brandingdir=debian/branding
  brandingdir=moz-objdir/$_brandingdir
  icondir="$pkgdir/usr/share/icons/hicolor"
  for i in 16 22 24 32 48 64 128 192 256 384; do
    convert -background none "$_brandingdir/${pkgname}_icon.svg" \
      -resize ${i}x${i}^ -gravity center -extent ${i}x${i} \
      "$brandingdir/default$i.png"
    install -Dm644 "$brandingdir/default$i.png" \
      "$icondir/${i}x${i}/apps/$pkgname.png"
  done

  install -Dm644 "$_brandingdir/${pkgname}_icon.svg" \
    "$icondir/scalable/apps/$pkgname.svg"
 
  install -d "$pkgdir/usr/share/applications"
  install -m644  "$srcdir/$pkgname.desktop" \
    "$pkgdir/usr/share/applications"

  # Use system-provided dictionaries
  rm -rf "$pkgdir/usr/lib/$pkgname/"{dictionaries,hyphenation}
  ln -s /usr/share/hunspell "$pkgdir/usr/lib/$pkgname/dictionaries"
  ln -s /usr/share/hyphen   "$pkgdir/usr/lib/$pkgname/hyphenation"

  # Workaround for now:
  # https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  ln -sf $pkgname "$pkgdir/usr/lib/$pkgname/$pkgname-bin"
}