# $Id: PKGBUILD 219544 2014-08-11 12:03:56Z schiv $
# Maintainer (Arch): Ray Rashif <schiv@archlinux.org>
# Contributor (Arch): tobias <tobias@archlinux.org>
# Contributor (Arch): see .contrib
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=hydrogen
pkgver=0.9.6
pkgrel=1.parabola1
pkgdesc="An advanced drum machine, without nonfree drumkits recommendation"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.hydrogen-music.org/"
depends=('libarchive' 'liblrdf' 'qt4' 'jack' 'libpulse')
optdepends=('rubberband')
makedepends=('cmake')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
source=("https://github.com/hydrogen-music/hydrogen/archive/$pkgver.tar.gz"
        'lrdf_raptor2.patch')
install=$pkgname.install
md5sums=('e4424926a88af82fb2048b3548723827'
         '6f15bc059d3c39e9c34e0fbac92baf61')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  # Change to list with only free licensed drumkits
  sed -i -e 's|www[.]hydrogen-music[.]org/feeds/drumkit_list[.]php|repo.parabolagnulinux.org/other/hydrogen-libre/feeds/drumkit_list.php|'\
  $(grep -rlI 'www[.]hydrogen-music[.]org/feeds/drumkit_list[.]php')

  # fix building with newer raptor
  # see https://bugs.archlinux.org/task/25060
  # see https://github.com/hydrogen-music/hydrogen/issues/194
  patch -Np1 -i "$srcdir/lrdf_raptor2.patch"

  # fix some pngs that break with newer libpng
  # see https://mailman.archlinux.org/pipermail/arch-dev-public/2013-May/024872.html
  #msg2 "Fixing PNGs, please wait..."
  #find -name '*.png' -exec optipng -quiet -force -fix {} +
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # lash will have to wait until I bring it into [extra] --schiv
  cmake . -DCMAKE_INSTALL_PREFIX=/usr \
          -DWANT_CPPUNIT=OFF \
          -DWANT_LRDF=ON
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: