# $Id: PKGBUILD 123130 2014-11-26 08:13:21Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): TingPing <tingping@tingping.se>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=hexchat
pkgver=2.10.2
pkgrel=1.parabola1
pkgdesc='A popular and easy to use graphical IRC (chat) client, without nonfree browser reference (Parabola rebranded)'
arch=('i686' 'x86_64' 'mips64el')
url='http://hexchat.github.io/'
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'gtk2' 'libcanberra' 'libnotify'
         'libproxy' 'pciutils')
makedepends=('intltool' 'iso-codes' 'perl' 'python')
optdepends=('enchant: Spell check'
            'perl: Perl plugin'
            'python: Python plugin')
install="${pkgname}.install"
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
source=("http://dl.hexchat.net/${pkgname}/${pkgname}-${pkgver}.tar.xz")
sha256sums=('87ebf365c576656fa3f23f51d319b3a6d279e4a932f2f8961d891dd5a5e1b52c')

prepare() {
  cd ${pkgname}-${pkgver}

#  sed 's/CFLAGS="$PERL_CFLAGS"/CFLAGS="$PERL_CFLAGS -fuse-ld=gold"/' -i configure

# Rebrand to Parabola
  sed -i 's#ArchLinux#Parabola GNU/Linux-libre#' plugins/sysinfo/parse.c

# Remove nonfree browser references
  sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
  sed -i '\|NAME Open Link| s|firefox -private %s\\n\\n";|iceweasel -private %s\\n\\n"\\\n		"NAME Open Link in Private Icecat Window\\n"		"CMD !icecat -private %s\\n\\n";|' src/common/hexchat.c
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure \
    --prefix='/usr' \
    --enable-python='python3' \
    --enable-textfe
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: