# $Id: PKGBUILD 97065 2013-09-12 08:20:08Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>
# Contributor: TingPing <tingping@tingping.se>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=hexchat
pkgname=hexchat-libre
pkgver=2.9.6
pkgrel=1
pkgdesc="A popular and easy to use graphical IRC (chat) client, without nonfree browser reference (Parabola rebranded)"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.hexchat.org/"
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'hicolor-icon-theme' 'libcanberra' 'libnotify' 'libproxy' 'libsexy' 'pciutils')
makedepends=('perl' 'python')
optdepends=('enchant: Spell check'
            'perl: Perl plugin'
            'python: Python plugin')
options=('!libtool')
install=${_pkgname}.install
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://dl.hexchat.org/hexchat/hexchat-${pkgver}.tar.xz")
sha256sums=('eaefc07867a6e546cd9e19a4ccc976b4736c759ba3f946020eeae3cd6f4684b0')

build() {
  cd ${_pkgname}-${pkgver}

# Rebrand to Parabola
  sed -i 's#ArchLinux#Parabola GNU/Linux-libre#' plugins/sysinfo/parse.c

# Remove nonfree browser references
  sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
  sed -i '\|NAME Open Link| s|firefox -private %s\\n\\n";|iceweasel -private %s\\n\\n";\n		"NAME Open Link in Private Icecat Window\\n"		"CMD !icecat -private %s\\n\\n";|' src/common/hexchat.c
  sed -i '\|NAME Open Link in Private Iceweasel Window| s|%s\\n\\n";|%s\\n\\n"\\|' src/common/hexchat.c

  ./configure --prefix='/usr' --enable-{python='python3',shm,spell='libsexy',textfe,xft}
  make
}

package() {
  cd ${_pkgname}-${pkgver}

  make DESTDIR="$pkgdir" install
}

# vim: ts=2 sw=2 et: