# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=ghostscript
pkgname=gnu-ghostscript
_gspkgver=9.10 # ghostscript-libre package version
_pkgver=9.06
pkgver=9.06.0
pkgrel=7
pkgdesc="An interpreter for the PostScript language maintained by a team of GNU programmers"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL3')
depends=('libxt' 'libcups' 'fontconfig' 'jasper' 'zlib' 'libpng>=1.5.7' 'libjpeg'
         'libtiff>=4.0.0' 'lcms2' 'dbus' 'libpaper')
makedepends=('gtk3' 'gnutls')
optdepends=('texlive-core:      needed for dvipdf'
            'gtk3:              needed for gsx')
conflicts=${_pkgname}
provides="${_pkgname}=${_gspkgver}"
url="https://www.gnu.org/software/${_pkgname}/"
source=(ftp://ftp.gnu.org/gnu/${_pkgname}/${pkgname}-${pkgver}.tar.xz
        ijs-automake.patch
        libtool.patch)
options=('!makeflags')
md5sums=('85a5e07a6b91937c157576293b381065'
         '83bcae456ad4c9fb790be483914dbeba'
         '5bd5d4966007b460deed866a30a0b3c8')

build() {
  cd ${pkgname}-${pkgver}

  # fix build with recent automake
  patch -p1 -i "$srcdir/ijs-automake.patch"

  # fix libtool version
  patch -Np1 -i ${srcdir}/libtool.patch

  # force it to use system-libs
  # keep heavily patched included openjpeg, leads to segfault with system openjpeg
  # https://bugs.archlinux.org/task/38226
  rm -rf jpeg libpng zlib jasper expat tiff lcms lcms2 freetype cups/libs # jbig2dec is in community

  ./configure --prefix=/usr \
	--enable-dynamic \
	--with-ijs \
	--with-jbig2dec \
	--with-omni \
	--with-x \
	--with-drivers=ALL\
	--with-fontpath=/usr/share/fonts/Type1:/usr/share/fonts \
	--enable-fontconfig \
	--enable-freetype \
	--enable-openjpeg \
	--without-luratech \
	--without-omni \
	--with-system-libtiff \
	--with-libpaper \
	--disable-compile-inits #--help # needed for linking with system-zlib
  make

  # Build IJS
  cd ijs
  sed -i "s:AM_PROG_CC_STDC:AC_PROG_CC:g" configure.ac
  ./autogen.sh
  ./configure --prefix=/usr --enable-shared --disable-static
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" \
	cups_serverroot="${pkgdir}"/etc/cups \
	cups_serverbin="${pkgdir}"/usr/lib/cups install soinstall

  # install missing doc files # http://bugs.archlinux.org/task/18023
  install -m 644 "${srcdir}"/${pkgname}-${pkgver}/doc/{Ps2ps2.htm,gs-vms.hlp,gsdoc.el,pscet_status.txt} "${pkgdir}"/usr/share/${_pkgname}/$_pkgver/doc/
  
  mkdir -p ${pkgdir}/usr/share/licenses/${_pkgname}
  install -m644 LICENSE ${pkgdir}/usr/share/licenses/${_pkgname}/

  # remove unwanted localized man-pages
  rm -rf "$pkgdir"/usr/share/man/[^man1]*

  # install IJS
  cd ijs
  make DESTDIR="${pkgdir}" install
  
  # remove filters that are now maintained in cups-filters as upstream home
  rm -rf "$pkgdir"/usr/lib/cups/filter/{gstopxl,gstoraster}
}