# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of glib2

pkgbase=glib2
pkgname=glib2-static
pkgver=2.48.0
pkgrel=1.1
pkgdesc="Common C routines used by GTK+ and other libs (static libraries only)"
url="http://www.gtk.org/"
arch=(i686 x86_64 armv7h)
makedepends=('python')
source=(http://ftp.gnome.org/pub/GNOME/sources/glib/${pkgver:0:4}/glib-$pkgver.tar.xz
        revert-warn-glib-compile-schemas.patch)
sha256sums=('744be6931ca914c68af98dc38ff6b0cf8381d65e335060faddfbf04c17147c34'
            '049240975cd2f1c88fbe7deb28af14d4ec7d2640495f7ca8980d873bb710cc97')

prepare() {
  cd glib-$pkgver
  patch -Rp1 -i ../revert-warn-glib-compile-schemas.patch
}
  
build() {
  cd glib-$pkgver
  ./configure --prefix=/usr --libdir=/usr/lib \
      --disable-fam --enable-static
  make
}

check() {
  cd glib-$pkgver
  #make -k check || :
}

package() {
  depends=('glib2')
  options=('staticlibs')
  license=('LGPL')

  cd glib-$pkgver
  make completiondir=/usr/share/bash-completion/completions DESTDIR="$pkgdir" install

  # remove conflicting files
  rm -vr ${pkgdir}/usr/{bin,lib/{glib-*,pkgconfig},include,share}
  rm -v ${pkgdir}/usr/lib/lib*.so*
}