# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of gdbm

_pkgname=gdbm
pkgname=gdbm-static
pkgver=1.11
pkgrel=1
pkgdesc="GNU database library (static libraries only)"
url="http://www.gnu.org/software/gdbm/gdbm.html"
license=('GPL3')
arch=('i686' 'x86_64' 'armv7h')
depends=('gdbm')
options=('!makeflags' 'staticlibs')
source=(ftp://ftp.gnu.org/gnu/gdbm/${_pkgname}-${pkgver}.tar.gz{,.sig}
        gdbm-1.10-zeroheaders.patch)
validpgpkeys=('325F650C4C2B6AD58807327A3602B07F55D0C732')
md5sums=('72c832680cf0999caedbe5b265c8c1bd'
         'SKIP'
         'ac255b10452005237836cd2d3a470733')

prepare() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  # Prevent gdbm from storing uninitialized memory content
  # to database files. This patch improves security, as the
  # uninitialized memory might contain sensitive informations
  # from other applications.
  # https://bugzilla.redhat.com/show_bug.cgi?id=4457
  # http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=208927
  patch -Np1 -i ../gdbm-1.10-zeroheaders.patch
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure --prefix=/usr --enable-libgdbm-compat
  make
}

check() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make check
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  # remove conflicting files
  rm -vr ${pkgdir}/usr/{bin,include,share}
  rm -v ${pkgdir}/usr/lib/lib*.so*
}