# $Id: PKGBUILD 185397 2013-05-13 19:05:20Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>

_pkgname=file-roller
pkgname=file-roller-libre
pkgver=3.8.2
pkgrel=1
pkgdesc="Create and modify archives, with unar recommendation included and nonfree unace recommendation removed"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
depends=('desktop-file-utils' 'gtk3' 'hicolor-icon-theme' 'dconf' 'libarchive' 'file' 'json-glib' 'libnotify')
makedepends=('intltool' 'gnome-doc-utils' 'pkg-config' 'libnautilus-extension' 'itstool' 'docbook-xsl')
optdepends=('unar: the free RAR uncompression utility'
            'zip: creates PKZIP-compatible .zip files'
            'p7zip: 7zip compression utility'
            'arj: ARJ archiver')
groups=('gnome-extra')
provides=("$_pkgname=$pkgver")
replaces=("$_pkgname")
conflicts=("$_pkgname")
options=('!libtool' '!emptydirs')
install=file-roller.install
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/gnome/sources/$_pkgname/${pkgver::3}/$_pkgname-$pkgver.tar.xz)
sha256sums=('b251b146d7966d770c98546e2152dbc17785ef3b8cf460f692829d0ac1cbe79e')

build() {
  cd $_pkgname-$pkgver

  ./configure --prefix=/usr --sysconfdir=/etc \
      --libexecdir=/usr/lib/file-roller \
      --localstatedir=/var --disable-static \
      --disable-schemas-compile
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}