# $Id: PKGBUILD 233910 2015-03-16 09:03:54Z jgc $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=evince
pkgver=3.14.2
pkgrel=1.parabola1
pkgdesc="Document viewer (PDF, Postscript, djvu, tiff, dvi, XPS, SyncTex support with gedit, comics books (cbr,cbz,cb7 and cbt)), with libarchive support"
url="https://wiki.gnome.org/Apps/Evince"
arch=(i686 x86_64 mips64el)
license=(GPL)
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
depends=(gtk3 libgxps libspectre gsfonts poppler-glib djvulibre t1lib libsecret desktop-file-utils dconf gsettings-desktop-schemas gnome-desktop)
makedepends=(itstool libnautilus-extension texlive-bin intltool gobject-introspection docbook-xsl python python2)
optdepends=('texlive-bin: DVI support'
	    'gvfs: bookmark support and session saving'
            'p7zip: cbz and cb7 compressed comic books'
            'tar: cbt compressed comic books'
            'libarchive: cbr compressed comic books')
groups=(gnome)
install=evince.install
options=('!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz
        libarchive.patch)
sha256sums=('4c591d0b879092a5f6c9140b75f15bdea3665a332e9b384957c453fd67bf0070'
            '023f01f40c5efb8bf245d97067b3ef1da74f96a0bc53e53eb3d990d6c29b9e5e')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../libarchive.patch
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr   --sysconfdir=/etc \
      --localstatedir=/var    --libexecdir=/usr/lib/evince \
      --disable-static        --enable-nautilus \
      --enable-pdf            --enable-tiff \
      --enable-djvu           --enable-dvi \
      --enable-t1lib          --enable-comics \
      --disable-scrollkeeper  --disable-schemas-compile \
      --enable-introspection --disable-browser-plugin
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}