# $Id: PKGBUILD 119836 2014-09-29 19:57:54Z flexiondotorg $
# Maintainer (Arch): Martin Wimpress <code@flexion.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=engrampa
pkgver=1.8.1
pkgrel=1.parabola1
pkgdesc="Archive manipulator for MATE, with unar recommendation included and nonfree unace recommendation removed"
url="http://mate-desktop.org"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
depends=('bzip2' 'caja' 'desktop-file-utils' 'gtk2' 'gzip' 'libarchive' 'tar')
makedepends=('mate-common' 'perl-xml-parser' 'yelp-tools' 'json-glib') # json-glib is necessary to enable unar support on the package
optdepends=('unar: for RAR uncompression'
            'zip: for ZIP archives' 'unzip: for ZIP archives'
            'p7zip: 7zip compression utility' 'arj: for ARJ archives'
            'yelp: for reading MATE help documents')
replaces=('mate-file-archiver' "${pkgname}-libre" "${pkgname}-parabola")
provides=('mate-file-archiver')
conflicts=('mate-file-archiver' "${pkgname}-libre" "${pkgname}-parabola")
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/1.8/${pkgname}-${pkgver}.tar.xz"
        fr-rpm-bsdtar.patch)
sha1sums=('2f3e655c2e4ac5a972c06591085557906748ac6f'
          '219b05a979bf6f249aaae27964f02345fd81168d')
install=${pkgname}.install

prepare() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    # This patch 'depends' on libarchive
    patch -Np1 -i "${srcdir}/fr-rpm-bsdtar.patch"
}

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    ./configure \
        --prefix=/usr \
        --libexecdir=/usr/lib/${pkgname} \
        --with-gtk=2.0 \
        --disable-static \
        --disable-packagekit
    make
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    make DESTDIR="${pkgdir}" install
}