# vim:set ft=sh:
# $Id: PKGBUILD 108140 2014-03-23 19:43:34Z idevolder $
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: (sirocco AT ngs.ru)

_pkgbase=doublecmd
pkgbase=doublecmd-libre
pkgname=('doublecmd-libre-gtk2' 'doublecmd-libre-qt')
pkgver=0.5.9
_helpver=0.5.5
pkgrel=1.1
url="http://doublecmd.sourceforge.net/"
arch=('i686' 'x86_64')
license=('GPL')
install="$_pkgbase.install"
provides=("$_pkgbase")
makedepends=('lazarus' 'qt4pas' 'gtk2')
optdepends=(
	'lua51: scripting'
	'p7zip: support for 7zip archives'
)
source=(
	"http://downloads.sourceforge.net/project/$_pkgbase/Double%20Commander%20Source/$_pkgbase-$pkgver-src.tar.gz"
	"http://downloads.sourceforge.net/project/$_pkgbase/Double%20Commander%20Source/$_pkgbase-help-$_helpver-src.tar.gz"
	"http://www.herecura.be/files/lazarus-20140321-2.tar.gz"
)

build() {
	cp -a $_pkgbase-$pkgver $_pkgbase-gtk
	cp -a $_pkgbase-$pkgver $_pkgbase-qt

	msg2 'build gtk'
	gtkdir="$srcdir/$_pkgbase-gtk"
	cd "$gtkdir"
	bsdtar -zxf "$srcdir/lazarus-20140321-2.tar.gz"
	sed -e "s/\\(export\\ lazbuild=\\).*/\\1\"\$(which lazbuild) --primary-config-path=${gtkdir//\//\\\/}\/lazarus\/lazarus-$CARCH\"/" -i build.sh
	sed -e "s/%%SRCDIR%%/${gtkdir//\//\\\/}/g" -i lazarus/packagefiles.xml
	./build.sh beta gtk2

	msg2 'build qt'
	qtdir="$srcdir/$_pkgbase-qt"
	cd "$qtdir"
	bsdtar -zxf "$srcdir/lazarus-20140321-2.tar.gz"
	sed -e "s/\\(export\\ lazbuild=\\).*/\\1\"\$(which lazbuild) --primary-config-path=${qtdir//\//\\\/}\/lazarus\/lazarus-$CARCH\"/" -i build.sh
	sed -e "s/%%SRCDIR%%/${qtdir//\//\\\/}/g" -i lazarus/packagefiles.xml
	./build.sh beta qt

}

package_doublecmd-libre-gtk2() {
	pkgdesc="twin-panel (commander-style) file manager (GTK), without nonfree libunrar recommendation"
	depends=('gtk2')
	conflicts=('doublecmd-libre-qt' 'doublecmd-gtk2' 'doublecmd-gtk2-libre')
	replaces=('doublecmd-gtk2' 'doublecmd-gtk2-libre')
	provides=("doublecmd-gtk2=${pkgver}" 'doublecmd-gtk2-libre')
	cd "$srcdir/$_pkgbase-gtk"
	./install/linux/install.sh --install-prefix="$pkgdir"

	# install doc
	cd "$srcdir/$_pkgbase-help-$_helpver"
	cp -a * "$pkgdir/usr/share/$_pkgbase/doc/"
}

package_doublecmd-libre-qt() {
	pkgdesc="twin-panel (commander-style) file manager (QT), without nonfree libunrar recommendation"
	depends=('qt4pas')
	conflicts=('doublecmd-libre-gtk2' 'doublecmd-qt' 'doublecmd-qt-libre')
	replaces=('doublecmd-qt' 'doublecmd-qt-libre')
	provides=("doublecmd-qt=${pkgver}" 'doublecmd-qt-libre')
	cd "$srcdir/$_pkgbase-qt"
	./install/linux/install.sh --install-prefix="$pkgdir"

	# install doc
	cd "$srcdir/$_pkgbase-help-$_helpver"
	cp -a * "$pkgdir/usr/share/$_pkgbase/doc/"
}

sha256sums=('d5b3c93b3029f4b0a45b7c9912d34f753445e031c93bc0268d4cb4c313d06ba4'
            '5c5d00187df811df0734bf751a581bce7e1bdd4cf4639b2a1101f1da8743daaf'
            '16560ad7403ffbee1800384768828e1fad924d03068c6248b68a78c393fc4e20')