# $Id: PKGBUILD 163295 2016-02-24 12:02:19Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): Stéphane Gaudreault <stephane@archlinux.org>
# Contributor (Arch): BlackEagle <ike.devolder@gmail.com>
# Contributor (Arch): Dany Martineau <dany.luc.martineau@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Kete <kete@ninthfloor.org>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=clementine
_pkgname=$pkgname-libre
pkgver=1.2.3
pkgrel=10.parabola1
pkgdesc='A modern music player and library organizer, without nonfree artwork and Spotify support'
url="http://www.$pkgname-player.org/"
license=('GPL')
arch=('i686' 'x86_64')
replaces=("$_pkgname")
conflicts=("$_pkgname")
depends=('chromaprint' 'glew' 'gstreamer0.10-base' 'libcdio' 'libgpod'
         'liblastfm' 'libmtp' 'libmygpo-qt' 'protobuf' 'qca-qt4' 'taglib')
makedepends=('cmake' 'boost' 'mesa' 'sparsehash')
optdepends=('gstreamer0.10-base-plugins: "Base" plugin libraries'
            'gstreamer0.10-good-plugins: "Good" plugin libraries'
            'gstreamer0.10-bad-plugins: "Bad" plugin libraries'
            'gstreamer0.10-ugly-plugins: "Ugly" plugin libraries'
            'gstreamer0.10-ffmpeg: FFmpeg plugin'
            'gvfs: Various devices support')
install="${pkgname}.install"
mksource=("${pkgname}-${pkgver}.tar.gz::https://github.com/$pkgname-player/${pkgname^}/archive/${pkgver}.tar.gz")
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
        'remove-nonfree-artwork-and-spotify.patch'
        'moognu.png'
        "${pkgname}-gcc5.1.patch"
        "${pkgname}-udisks-namespace.patch")
mksha256sums=('7df5650445a005c09f5f0e1a1b0d077037c37ecbe4ee77baf9d45f121308a1bf')
sha256sums=('30fde23dde610b610d2172e94e4bd87f4a86afaeb4d9b6c8a5be8cbab0502eea'
            '48bfbf42c84ac1891021638627c10780194fcc59eda1c69e157be3aebe8ee10b'
            'c6918617769152f3617c61f721819e69d03f671b85760b11cfe45abd53955bc4'
            'b03c190b881520c3233ed8f5804b518e9e699c6f773ab227f36133f422b786e1'
            'a7c2764576cee303a57e4efe6a5dbd583a66de8a15aee738bd92d4bb21786008')

mksource() {
  cd ${pkgname^}-${pkgver}

  # remove nonfree artwork for the Nyan Cat plugin
  # https://labs.parabola.nu/issues/329
  rm -v data/nyancat.png
}

prepare() {
  cd ${pkgname^}-${pkgver}

  # remove nonfree artwork and Spotify references
  patch -Np1 -i ../remove-nonfree-artwork-and-spotify.patch

  # remove Spotifyblob folders
  rm -rv ext/{$pkgname-spotifyblob,lib${pkgname}-spotifyblob}

  # remove Spotify files
  rm -v cmake/SpotifyVersion.cmake
  rm -v data/spotify-attribution.png
  rm -v data/icons/svg/spotify.svg
  rm -v data/schema/schema-30.sql
  rm -v src/{globalsearch/spotifysearchprovider.{cpp,h},internet/spotify{blobdownloader.{cpp,h},server.{cpp,h},service.{cpp,h},settingspage.{cpp,h,ui}}}

  # move free Nyan Cat replacement mascot (MooGNU) to the source code
  # https://labs.parabola.nu/issues/329
  install -m644 -v ../moognu.png data

  # create a blank file because it's a dependency for Clementine
  touch data/schema/schema-30.sql

  patch -Np1 -i ../clementine-gcc5.1.patch
  patch -Np1 -i ../clementine-udisks-namespace.patch
}

build() {
  cd ${pkgname^}-${pkgver}

  if [[ -d build ]]; then
    rm -rf build
  fi
  mkdir build && cd build

  cmake .. \
    -DCMAKE_BUILD_TYPE='Release' \
    -DCMAKE_INSTALL_PREFIX='/usr'
  make
}

package() {
  cd ${pkgname^}-${pkgver}/build

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: