# $Id$
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: monson <holymonson@gmail.com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: David Manouchehri <david@davidmanouchehri.com>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgname=cgminer-libre
_pkgflag=libre
pkgver=2.11.3
_build=
pkgrel=1
pkgdesc="Multi-threaded multi-pool CPU and GPU miner for bitcoin, forked from cpuminer, with free OpenCL support."
url='http://forum.bitcoin.org/index.php?topic=28402.0'
license=('GPL3')
arch=('i686' 'x86_64' 'mips64el')
depends=('curl' 'libcl-libre')
makedepends=('opencl-headers')
provides=(${pkgname%-$_pkgflag}=$pkgver)
conflicts=${pkgname%-$_pkgflag}
replaces=${pkgname%-$_pkgflag}
source=("http://ck.kolivas.org/apps/${pkgname%-$_pkgflag}/${pkgname%-$_pkgflag}-$pkgver.tar.bz2"
        "${pkgname%-$_pkgflag}.conf.d"
        "${pkgname%-$_pkgflag}.service")
backup=("etc/conf.d/${pkgname%-$_pkgflag}" "etc/${pkgname%-$_pkgflag}.conf")

[ "$CARCH" == "x86_64" ] && makedepends+=('yasm')

build() {
  cd "$srcdir"
  cd ${pkgname%-$_pkgflag}-$pkgver${_build}

  # Use in-tree jansson since it is not compatible with jansson 2.0
  #sed -e 's/^AC_CHECK_LIB(jansson, json_loads, request_jansson=false, request_jansson=true)$/request_jansson=true/' -i configure.ac

  # Here you may want to use custom CFLAGS
  #export CFLAGS="-O2 -march=native -mtune=native -msse2"

  ./configure --prefix=/usr --enable-cpumining --disable-adl
  
  make
}

package() {
  cd "$srcdir"/${pkgname%-$_pkgflag}-$pkgver${_build}

  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir"/${pkgname%-$_pkgflag}.service "$pkgdir"/usr/lib/systemd/system/${pkgname%-$_pkgflag}.service
  install -Dm644 "$srcdir"/${pkgname%-$_pkgflag}.conf.d "$pkgdir"/etc/conf.d/${pkgname%-$_pkgflag}
  sed 's#/usr/local/bin#/usr/bin#g' example.conf > ${pkgname%-$_pkgflag}.conf
  install -Dm644 ${pkgname%-$_pkgflag}.conf "$pkgdir"/etc/${pkgname%-$_pkgflag}.conf
}

md5sums=('fd2c69f943353fbc9723a5526d82c1b6'
         'fe4a243fabe24608f5c05e40f0f118f6'
         'bd76fc92fedce18c59ccea2aa79cc664')