# $Id: PKGBUILD 123283 2014-11-29 13:14:25Z fyan $
# Maintainer (Arch): Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor (Arch): Andy Weidenbaum <archbaum@gmail.com>

pkgname=bfgminer
pkgver=5.0.0
pkgrel=1.parabola1
pkgdesc="Bitcoin miner featuring overclocking, monitoring, fan speed control and remote management. For FPGA/GPU/CPU Bitcoin mining, with opencl-mesa recommendation"
arch=('i686' 'x86_64' 'mips64el')
depends=('curl' 'jansson' 'libevent' 'libmicrohttpd' 'libusb' 'lm_sensors')
makedepends=('uthash' 'yasm')
optdepends=('opencl-mesa: OpenCL implementation for Mesa')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
url='http://bfgminer.org/'
license=('GPL3')
source=(http://luke.dashjr.org/programs/bitcoin/files/$pkgname/$pkgver/$pkgname-$pkgver.txz
        remove-dangerous-rpath.patch)
sha256sums=('f1dada4d83737f7bc9623ad695a07a88808d8103c9c7617ce18825d241e328fd'
            '27d89695ff963dd8f66654b9d454aa725c7db769def708513188fe0a496fda4d')

prepare() {
  cd "$srcdir"/$pkgname-$pkgver

  patch -p1 -i "${srcdir}"/remove-dangerous-rpath.patch
}

build() {
  cd "$srcdir"/$pkgname-$pkgver

  ./configure --prefix=/usr \
    --sbindir=/usr/bin \
    --enable-cpumining \
    --enable-bfsb \
    --enable-metabank \
    --enable-scrypt \
    --enable-opencl \
    --with-udevrulesdir=/usr/lib/udev/rules.d
  # --enable-knc (FS#33640)
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver

  make DESTDIR="$pkgdir" install
}