# $Id: PKGBUILD 94236 2013-07-17 13:44:25Z tredaelli $
# Maintainer: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>

_pkgname=bfgminer
pkgname=bfgminer-libre
pkgver=3.1.3
pkgrel=1
pkgdesc="Bitcoin miner featuring overclocking, monitoring, fan speed control and remote management. For FPGA/GPU/CPU Bitcoin mining, without nonfree OpenCL recommendation."
arch=('i686' 'x86_64' 'mips64el')
depends=('curl' 'jansson' 'libusbx' 'lm_sensors')
makedepends=('uthash' 'yasm')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
url='https://bitcointalk.org/index.php?topic=168174.0'
license=('GPL3')
options=(!libtool)
source=(http://luke.dashjr.org/programs/bitcoin/files/$_pkgname/$pkgver/$_pkgname-$pkgver.tbz2
        remove-dangerous-rpath.patch)
sha256sums=('07964687daf8c6ba0a11f349b6b139e4d35078cdd013935f9331b28feced0500'
            'd26d07ca23ae25798c4db37cfda1a6a76f22d06e73efab1ddf62b3e1a7eef04c')

prepare() {
  cd "$srcdir"/$_pkgname-$pkgver

  patch -p0 < "${srcdir}"/remove-dangerous-rpath.patch
  NOSUBMODULES=1 ./autogen.sh
}

build() {
  cd "$srcdir"/$_pkgname-$pkgver

  ./configure --prefix=/usr --enable-cpumining --enable-scrypt
  make
}

package() {
  cd "$srcdir"/$_pkgname-$pkgver

  make DESTDIR="$pkgdir" install
}