# $Id$
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=audacious-plugins-libre
pkgver=2.4.4
pkgrel=3
pkgdesc='Plugins for Audacious without unfree plugins'
arch=('i686' 'x86_64')
url='http://audacious-media-player.org/'
license=('GPL')
provides=("audacious-plugins=$pkgver")
replaces=("${pkgname%-libre}")
conflicts=("${pkgname%-libre}")

makedepends=("audacious>=${pkgver}"
             'alsa-lib' 'pulseaudio' 'jack' 'lame' 'libvorbis' 'flac'
             'faad2' 'ffmpeg' 'fluidsynth' 'libcdio' 'libsidplay' 'wavpack'
             'libnotify' 'lirc-utils' 'curl' 'libmtp'
             'neon' 'libmms' 'libcue')

optdepends=('alsa-lib: Advanced Linux Sound Arch. output'
            'pulseaudio: PulseAudio output'
            'jack: Jack Audio Connection Kit output'
            'lame: FileWriter MP3 output'
            'libvorbis: Vorbis input, FileWriter Vorbis output'
            'flac: FLAC input, FileWriter FLAC output'

            'faad2: AAC input'
            'ffmpeg: ffaudio input'
            'fluidsynth: MIDI FluidSynth backend input'
            'libcdio: CD Digital Audio input'
            'libsidplay: Commodore 64 audio input'
            'wavpack: WavPack input'

            'libnotify: libnotify OSD'
            'lirc-utils: LIRC'
            'curl: AudioScrobbler Client'
            'libmtp: Upload to MTP device'

            'neon: neon-based http transport'
            'libmms: libmms-based mms transport'
            'libcue: CUE playlist format')

source=("http://repo.parabolagnulinux.org/other/$pkgname-$pkgver.tar.gz")

# Source PKGBUILD and run this function from the shell
mksource(){
    tmpdir=$(mktemp -d /tmp/audacious-XXXX)
    pushd $tmpdir >/dev/null
    wget "http://distfiles.atheme.org/${pkgname%-libre}-$pkgver.tgz" -O - -q | tar xzf -

	rm -rvf ${pkgname%-libre}-$pkgver/src/{u,p}sf/

    mv -v ${pkgname%-libre}-$pkgver ${pkgname}-$pkgver

    tar czf ${pkgname}-${pkgver}.tar.gz ${pkgname}-${pkgver}/

    echo "You can find the sources at $tmpdir"

    popd >/dev/null
}

build() {
	cd "$srcdir/$pkgname-$pkgver"

	sed 's/libavcore >= 0.12.0//g' -i configure # FS#23549

	[[ $CARCH == x86_64 ]] && extraopts='' || extraopts='--disable-sse2'
	./configure \
		--prefix=/usr \
		--enable-chardet \
		--enable-amidiplug \
		--disable-adplug \
		--disable-psf \
		$extraopts \
		--disable-projectm # no support for projectm-2.0.1, cf. FS#21344
		                   # would require libvisual-projectm in make/optdeps
	make
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	make DESTDIR="$pkgdir" install
}
md5sums=('df761a2d07e2ad1221c5fe61fa32dcb0')