# $Id: PKGBUILD 116819 2014-08-04 07:10:28Z tpowa $
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): mortzu <me@mortzu.de>
# Contributor (Arch): fnord0 <fnord0@riseup.net>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Márcio Silva <coadde@parabola.nu>

_kernelname=
_basekernel=3.16
_pkgrel=1

if [[ ${_kernelname} == "" ]]; then
  _basekernel=${_basekernel}
  _pkgrel=11.3
elif [[ ${_kernelname} == -lts ]]; then
  _basekernel=3.14
  _pkgrel=7
elif [[ ${_kernelname} == -grsec ]]; then
  _basekernel=3.15
  _pkgrel=${_pkgrel}
elif [[ ${_kernelname} == -lts-knock ]]; then
  _basekernel=3.10
  _pkgrel=${_pkgrel}
elif [[ ${_kernelname} == -rt ]]; then
  _basekernel=3.14
  _pkgrel=${_pkgrel}
elif [[ ${_kernelname} == -pae ]]; then
  _basekernel=${_basekernel}
  _pkgrel=${_pkgrel}
elif [[ ${_kernelname} == -xen ]]; then
  _basekernel=${_basekernel}
  _pkgrel=${_pkgrel}
fi

_pkgname=acpi_call
pkgname=${_pkgname}${_kernelname}-parabola
pkgver=1.1.0
pkgrel=${_pkgrel}
_extramodules=extramodules-${_basekernel}${_kernelname}
pkgdesc="A linux kernel module that enables calls to ACPI methods through /proc/acpi/call (built for the linux-libre${_kernelname} kernel package)"
arch=('i686' 'x86_64' 'mips64el')
url="http://github.com/mkottman/${_pkgname}"
license=('GPL')

# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
depends=("linux-libre${_kernelname}>=${_basekernel}" "linux-libre${_kernelname}<${_toohigh}")
makedepends=("linux-libre${_kernelname}-headers>=${_basekernel}" "linux-libre${_kernelname}-headers<${_toohigh}")

replaces=("${_pkgname}${_kernelname}" "${_pkgname}-libre${_kernelname}")
[[ -n ${_kernelname} ]] && replaces+=("${_pkgname}-parabola${_kernelname}")
conflicts=("${_pkgname}${_kernelname}" "${_pkgname}-libre${_kernelname}")
[[ -n ${_kernelname} ]] && conflicts+=("${_pkgname}-parabola${_kernelname}")
provides=("${_pkgname}${_kernelname}=${pkgver}")

install='kmod.install'
source=("${url}/archive/v${pkgver}.tar.gz")
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  make KVERSION="${_kernver}"
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  # Set the correct extramodules directory for install
  cp -f "${startdir}/${install}" "${startdir}/${install}.pkg"
  true && install=${install}.pkg
  sed -i "s/^_EXTRAMODULES=.*/_EXTRAMODULES="${_extramodules}"/" "${startdir}/${install}"

  # Actually install
  install -dm 755 "${pkgdir}"/usr/lib/{modules/${_extramodules},modules-load.d}
  install -m 644 ${_pkgname}.ko "${pkgdir}"/usr/lib/modules/${_extramodules}
  gzip "${pkgdir}"/usr/lib/modules/${_extramodules}/${_pkgname}.ko
  echo ${_pkgname} > "${pkgdir}"/usr/lib/modules-load.d/${_pkgname}${_kernelname}.conf

  install -dm 755 "${pkgdir}"/usr/share/${_pkgname}${_kernelname}
  cp -dr --no-preserve='ownership' {examples,support} "${pkgdir}"/usr/share/${_pkgname}${_kernelname}/
}

# vim: ts=2 sw=2 et: