# $Id: PKGBUILD 215017 2014-06-11 14:14:55Z jgc $
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Maël Lavault <moimael@neuf.fr>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgbase=abiword
pkgbase=abiword-libre
pkgname=('abiword-libre' 'abiword-libre-plugins')
pkgver=3.0.0
pkgrel=3
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url='http://www.abisource.com'
makedepends=('pkgconfig' 'asio' 'boost' 'fribidi' 'goffice' 'libwmf' 'wv'
             'link-grammar' 'gtkmathview' 'aiksaurus' 'libxslt' 'enchant'
             'libots' 'libwpg' 'librsvg' 'loudmouth' 'libsoup' 'psiconv'
             'redland' 'libical')
options=('!makeflags')
source=(http://abisource.com/downloads/$_pkgbase/$pkgver/source/$_pkgbase-$pkgver.tar.gz
        fix_crash_saving_pdf.patch
        abiword-3.0.0-librevenge.patch
        liberation-fonts.patch)
md5sums=('8d9c41cff3a8fbef8d0c835c65600e65'
         'c3336f5ac7d227ff755c7e42459f20e1'
         '6fc2d653d3b814bbfd9b0d71c69c4796'
         'e7ef4d436469ae4b24b0f784b09ab023')

prepare() {
  cd $_pkgbase-$pkgver

  # fix FS#39652 - http://bugzilla.abisource.com/show_bug.cgi?id=13586#c2
  patch -Np2 -i ${srcdir}/fix_crash_saving_pdf.patch
  
  # fix build with librevenge based import filters
  patch -Np0 -i ${srcdir}/abiword-3.0.0-librevenge.patch

  # replace nonfree fonts support to liberation fonts
  patch -Np1 -i "${srcdir}/liberation-fonts.patch"

  find plugins -name plugin.m4 | xargs cat > plugin-configure.m4
  
  #aclocal -I m4 --install
  #autoconf
  libtoolize --force
  autoreconf -fi
}


build() {
  cd $_pkgbase-$pkgver

# Collab plugin is somehow broken:
# part service
#In file included from ./../../../backends/service/xp/RealmConnection.h:33:0,
#                 from ./../../../backends/service/xp/AbiCollabSaveInterceptor.h:23,
#                 from ./../../../backends/service/xp/ServiceAccountHandler.h:33,
#                 from ServiceUnixAccountHandler.h:23,
#                 from ServiceUnixAccountHandler.cpp:20:
#./../../../core/sync/xp/SynchronizedQueue.h:32:1: error: expected class-name before '{' token
# {
# part tcp
#In file included from ./../../../backends/tcp/xp/IOServerHandler.h:29:0,
#                 from ./../../../backends/tcp/xp/TCPAccountHandler.h:25,
#                 from TCPUnixAccountHandler.h:22,
#                 from TCPUnixAccountHandler.cpp:20:
#./../../../backends/tcp/xp/Session.h:34:63: error: expected class-name before ',' token
# class Session : public Synchronizer, public boost::noncopyable, public boost::enable_shared_from_this<Session>

  ./configure --prefix=/usr \
    --enable-shared \
    --disable-static \
    --enable-clipart \
    --enable-templates \
    --disable-builtin-plugins \
    --enable-plugins \
    --disable-collab-backend-service \
    --disable-collab-backend-tcp
  make
}

package_abiword-libre() {
  pkgdesc='Fully-featured word processor, without nonfree fonts support'
  depends=('fribidi' 'wv' 'goffice' 'librsvg' 'enchant' 'desktop-file-utils'
           'redland' 'libical' 'gtk-update-icon-cache')
  install=$_pkgbase.install
  optdepends=('abiword-libre-plugins')
  conflicts=("abiword-libre-plugins<${pkgver}-${pkgrel}" 'abiword')
  replaces=('abiword')
  provides=("abiword=$pkgver")

  cd $_pkgbase-$pkgver
  make DESTDIR="$pkgdir" install

  # split out plugins, there's no Makefile target for a clean way
  mkdir ${srcdir}/_pluginsdir
  mv "$pkgdir"/usr/lib/abiword-${pkgver%.*}/plugins ${srcdir}/_pluginsdir
}

package_abiword-libre-plugins() {
  pkgdesc='Additional plugins for Abiword, without nonfree fonts support'
  depends=("abiword-libre=${pkgver}-${pkgrel}" 'loudmouth' 'libwpg' 'libwmf' 'link-grammar' 
           'gtkmathview' 'aiksaurus' 'libxslt' 'libsoup' 'libots' 'libgsf' 'psiconv')
  conflicts=('abiword-plugins')
  replaces=('abiword-plugins')
  provides=("abiword-plugins=$pkgver")

  install -dm755 ${pkgdir}/usr/lib/abiword-${pkgver%.*}
  mv ${srcdir}/_pluginsdir/plugins ${pkgdir}/usr/lib/abiword-${pkgver%.*}/
}