# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=libretools
pkgname=(libretools libretools-mips64el librelib gitget xbs)
pkgdesc="Programs for Parabola development"
url="https://projects.parabolagnulinux.org/packages/libretools.git/"
license=('GPL3' 'GPL2')

pkgver=20140630
_libretools_commit=5a84f3c84a1f3275f5b3ab51b1cf90327f52b9b2
_devtools_commit=d732aae2ca57430f3dd95c0ed4dcc05df4014f91
md5sums=('14a272e6b69c05493b16d84a247a1e17'
         '615db785531757d3a849614bb117fba4')

_packages_url=https://projects.parabolagnulinux.org/packages
source=($_packages_url/libretools.git/snapshot/libretools-$_libretools_commit.tar.bz2
	$_packages_url/devtools-par.git/snapshot/devtools-par-$_devtools_commit.tar.bz2)

pkgrel=1
arch=('any')
makedepends=(emacs ronn) # emacs --batch is used during the build to process text
checkdepends=(sh-roundup)

build() {
  cd "$srcdir"
  ln -sf devtools-par-$_devtools_commit devtools-par
  cd "$srcdir/$pkgbase-$_libretools_commit"
  make build-libretools build-libretools-mips64el build-librelib build-doc
}

check() {
  cd "$srcdir/$pkgbase-$_libretools_commit"

  SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
}

package_librelib() {
  pkgdesc="The shell library portion of libretools"
  license=(GPL2)
  depends=(
    wget # `blacklist`
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-librelib DESTDIR="$pkgdir"
}

package_gitget() {
  pkgdesc="A simple to use downloader for git URLs"
  license=(GPL2)
  depends=("librelib=$pkgver" git)

  provides=("libregit=$pkgver")
  conflicts=("libregit")
  replaces=("libregit")

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-gitget DESTDIR="$pkgdir"
}

package_xbs() {
  pkgdesc='A tool for working with arbitrary ABS-like build systems'
  license=(GPL2)
  depends=(
    "gitget=$pkgver" # for helper-abslibre
    "librelib=$pkgver"
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-xbs DESTDIR="$pkgdir"
}

package_libretools() {
  backup=(etc/libretools.conf etc/libretools.d/chroot.conf etc/libretools.d/librefetch.conf)
  install=libretools.install
  replaces=(chroottools)
  conflicts=(devtools chroottools)

  depends=(
    "librelib=$pkgver"
    "xbs=$pkgver" # `createworkdir`, `librestage`
    "systemd>=212" # force newer systemd
    arch-install-scripts # `archroot` uses `pacstrap`
    openssh # `librerelease`
    rsync # `librerelease` and `makechrootpkg.sh`
    subversion # `diff-unfree`
    tokyocabinet # `treepkg`
    wget # `aur`
  )
  optdepends=('namcap: to check package files')

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools install-doc DESTDIR="$pkgdir"
}

package_libretools-mips64el() {
  pkgdesc="Scripts for Parabola development (for mips64el architecture)"
  license=(GPL3)
  depends=("$pkgbase=$pkgver"
    git # mips-add
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools-mips64el DESTDIR="$pkgdir"
}