# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=lib32-$pkgbase-$_pkgname
pkgver=10.4.2
pkgrel=1
pkgdesc='Mesa 3-D OpenCL library and ICD loader (32-bit)'
arch=('x86_64')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase-$_pkgname" "lib32-$pkgbase" 'lib32-libclc' 'lib32-clang')
# please use libretools, install "multilib-devel" on chroot and add
#  "CHROOTEXTRAPKG=(multilib-devel)" on "/etc/libretools.d/chroot.conf" file.
makedepends=('dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2')
provides=("lib32-$_pkgname")
conflicts=("lib32-$_pkgname" "lib32-$_pkgname-libre" 'lib32-opencl-nvidia' 'lib32-opencl-nvidia-304xx')
replaces=("lib32-$_pkgname" "lib32-$_pkgname-libre" 'lib32-opencl-nvidia' 'lib32-opencl-nvidia-304xx')
source=(ftp://ftp.freedesktop.org/pub/$pkgbase/$pkgver/${pkgbase^}Lib-$pkgver.tar.bz2{,.sig})
sha512sums=('dcf479c28de8d13e6e3348c18b020944c085a476a419110d4da36df93bd1961c2b04989abbc737820f9408bbc007c64a69d2348871c661be80a6a06a8b7a0a04'
            'SKIP')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>

build() {
  cd $srcdir/${pkgbase^}-$pkgver

  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  export LLVM_CONFIG='/usr/bin/llvm-config32'
  if [[ $(uname -o) == GNU/Hurd ]]; then
    export _HOST=i686-unknown-gnu
  elif [[ $(uname -o) == GNU/Linux ]]; then
    export _HOST=i686-unknown-linux-gnu
  elif [[ $(uname -o) == GNU/kFreeBSD ]]; then
    export _HOST=i686-unknown-kfreebsd-gnu
  fi

  autoreconf -vfi # our automake is far too new for their build system :)

  ./configure --prefix=/usr --libdir=/usr/lib32 --host=$_HOST \
    --sysconfdir=/etc \
    --enable-llvm-shared-libs \
    --enable-opencl \
    --with-clang-libdir=/usr/lib32
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver

  install -vm755 -d $pkgdir/usr/lib32/
  mv -v $srcdir/fakeinstall/usr/lib32/libOpenCL* $pkgdir/usr/lib32/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: