From 9e6b0435d589e32ab93291d4a119fff5892c680e Mon Sep 17 00:00:00 2001
From: Omar Vega Ramos <ovruni@gnu.org.pe>
Date: Wed, 10 Feb 2016 13:03:40 -0500
Subject: bitlbee-libpurple-3.4.1-1.parabola1: updating version

---
 pcr/bitlbee-libpurple/PKGBUILD | 57 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 pcr/bitlbee-libpurple/PKGBUILD

(limited to 'pcr/bitlbee-libpurple/PKGBUILD')

diff --git a/pcr/bitlbee-libpurple/PKGBUILD b/pcr/bitlbee-libpurple/PKGBUILD
new file mode 100644
index 000000000..d57f08e04
--- /dev/null
+++ b/pcr/bitlbee-libpurple/PKGBUILD
@@ -0,0 +1,57 @@
+
+# Contributor (Arch): Fernando Jiménez Solano (fjim) <fjim@sdfeu.org>
+# Contributor (Arch): FUBAR <mrfubar@gmail.com>
+# Contributor (Arch): simo <simo@archlinux.org>
+# Contributor (Arch): Jeff 'codemac' Mickey <jeff@archlinux.org>
+# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
+# Contributor (Arch): Gaetan Bisson <bisson@archlinux.org>
+# Contributor (Arch): Dave Reisner <dreisner@archlinux.org>
+# Maintainer (Arch): dx <dx@dxzone.com.ar>
+# Maintainer: Márcio Silva <coadde@parabola.nu>
+
+pkgname=bitlbee-libpurple
+_pkgname=bitlbee
+pkgver=3.4.1
+pkgrel=1.parabola1
+pkgdesc='Brings instant messaging (XMPP, MSN, Yahoo!, AIM, ICQ, Twitter) to IRC, without nonfree Skype support'
+url='http://www.bitlbee.org/'
+license=('GPL')
+arch=('i686' 'x86_64' 'armv7h')
+depends=('gnutls' 'glib2' 'libpurple')
+makedepends=('libotr' 'python')
+optdepends=('libotr: for OTR encryption support')
+provides=("bitlbee=${pkgver}")
+conflicts=('bitlbee')
+source=("http://get.bitlbee.org/src/${_pkgname}-${pkgver}.tar.gz"
+        'bitlbee.tmpfiles')
+sha1sums=('b77311b538ec1c584694784f119b99fb6b3f4859'
+          '3695ed2fe22436c4d0fc3ead829f7d1f89bc491c')
+backup=('etc/bitlbee/bitlbee.conf'
+        'etc/bitlbee/motd.txt')
+install=${_pkgname}.install
+
+build() {
+  cd "${_pkgname}-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --etcdir=/etc/bitlbee \
+    --sbindir=/usr/bin \
+    --pidfile=/run/bitlbee/bitlbee.pid \
+    --ipcsocket=/run/bitlbee/bitlbee.sock \
+    --systemdsystemunitdir=/usr/lib/systemd/system \
+    --ssl=gnutls \
+    --strip=0 \
+    --otr=plugin \
+    --skype=0 \
+    --purple=1
+
+  make
+}
+
+package() {
+  make -C "${_pkgname}-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev,-systemd}
+
+  install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
+  install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
+}
-- 
cgit v1.2.3-2-g168b