From 1c409b588e3bbf51b7861bb06a5d8e9282fb27f1 Mon Sep 17 00:00:00 2001
From: Omar Vega Ramos <ovruni@gnu.org.pe>
Date: Sun, 13 Sep 2015 21:38:58 -0500
Subject: java-commons-io: add new package to [libre]

---
 libre/java-commons-io/PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 libre/java-commons-io/PKGBUILD

(limited to 'libre')

diff --git a/libre/java-commons-io/PKGBUILD b/libre/java-commons-io/PKGBUILD
new file mode 100644
index 000000000..cc82249ec
--- /dev/null
+++ b/libre/java-commons-io/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer (Arch): Lukas Fleischer <archlinux at cryptocrack dot de>
+# Contributor (Arch): Stefan Husmann <stefan-husmann@t-online.de>
+# Contributor (Arch): Simon Lipp <sloonz+aur@gmail.com>
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+_pkgname=commons-io
+pkgname=java-${_pkgname}
+pkgver=2.4
+pkgrel=1
+pkgdesc="IO related classes for Java."
+arch=('any')
+url="https://commons.apache.org/io/"
+license=('APACHE')
+depends=('java-runtime')
+makedepends=('apache-ant' 'jh')
+source=("https://archive.apache.org/dist/commons/io/source/${_pkgname}-${pkgver}-src.tar.gz")
+md5sums=('a3e251952d75991fc8df40ad6b605094')
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-src"
+  ant jar javadoc -Dcomponent.version=2.4
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-src"
+
+  # Install license file
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+
+  # Install documentation
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -r "target/apidocs" "${pkgdir}/usr/share/doc/${pkgname}"
+
+  # Install Maven artifacts
+  export DESTDIR=${pkgdir}
+  jh mvn-install ${_pkgname} ${_pkgname} ${pkgver} \
+    "${srcdir}/${_pkgname}-${pkgver}-src/pom.xml" \
+    "${srcdir}/${_pkgname}-${pkgver}-src/target/${_pkgname}-${pkgver}.jar" \
+    "${_pkgname}.jar"
+  ln -s "/usr/share/java/${_pkgname}.jar" \
+    "${pkgdir}/usr/share/java/${_pkgname}-${pkgver}.jar"
+}
\ No newline at end of file
-- 
cgit v1.2.3-2-g168b