From e80ca4f5afd47c0913d7990ab32e718984aa5caf Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Andr=C3=A9=20Fabian=20Silva=20Delgado?=
 <emulatorman@parabola.nu>
Date: Mon, 9 Nov 2015 16:00:09 -0300
Subject: qutebrowser-git: add new package to [pcr] ->
 https://labs.parabola.nu/issues/855

---
 pcr/qutebrowser-git/PKGBUILD                | 70 +++++++++++++++++++++++++++++
 pcr/qutebrowser-git/qutebrowser-git.install | 12 +++++
 2 files changed, 82 insertions(+)
 create mode 100644 pcr/qutebrowser-git/PKGBUILD
 create mode 100644 pcr/qutebrowser-git/qutebrowser-git.install

diff --git a/pcr/qutebrowser-git/PKGBUILD b/pcr/qutebrowser-git/PKGBUILD
new file mode 100644
index 000000000..993735370
--- /dev/null
+++ b/pcr/qutebrowser-git/PKGBUILD
@@ -0,0 +1,70 @@
+# Maintainer (Arch): Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
+# vim: set ts=2 sw=2 et ft=sh:
+
+pkgname=qutebrowser-git
+pkgver=r6195.41f7c11
+pkgrel=1
+pkgdesc="A keyboard-driven, vim-like browser based on PyQt5 and QtWebKit"
+arch=(any)
+url="http://www.qutebrowser.org/"
+license=('GPL')
+depends=('python>=3.4' 'python-setuptools' 'python-pyqt5>=5.2' 'qt5-base>=5.2'
+         'qt5-webkit>=5.2' 'libxkbcommon-x11' 'python-pypeg2' 'python-jinja'
+         'python-pygments' 'xdg-utils' 'desktop-file-utils' 'python-yaml')
+makedepends=('asciidoc' 'source-highlight' 'git')
+optdepends=(
+  'python-colorlog: colored logging output'
+  'gst-libav: media playback'
+  'gst-plugins-base: media playback'
+  'gst-plugins-good: media playback'
+  'gst-plugins-bad: media playback'
+  'gst-plugins-ugly: media playback'
+)
+options=(!emptydirs)
+conflicts=('qutebrowser')
+provides=('qutebrowser')
+source=('git+https://github.com/The-Compiler/qutebrowser.git'
+        'qutebrowser-git.install')
+sha256sums=('SKIP'
+            '4a88871e91f894890ce96feb620e4174c686db12e4fa91b5a7306454dc96bf67')
+install=qutebrowser-git.install
+
+pkgver() {
+  cd "$srcdir/qutebrowser"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$srcdir/qutebrowser"
+  python scripts/asciidoc2html.py
+  a2x -f manpage doc/qutebrowser.1.asciidoc
+  python setup.py build
+}
+
+package() {
+  cd "$srcdir/qutebrowser"
+  python setup.py install --root="$pkgdir/" --optimize=1
+  install -Dm644 doc/qutebrowser.1 "$pkgdir/usr/share/man/man1/qutebrowser.1"
+  install -Dm644 qutebrowser.desktop \
+    "$pkgdir/usr/share/applications/qutebrowser.desktop"
+  install -Dm644 icons/qutebrowser-16x16.png \
+    "$pkgdir/usr/share/icons/hicolor/16x16/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-24x24.png \
+    "$pkgdir/usr/share/icons/hicolor/24x24/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-32x32.png \
+    "$pkgdir/usr/share/icons/hicolor/32x32/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-48x48.png \
+    "$pkgdir/usr/share/icons/hicolor/48x48/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-64x64.png \
+    "$pkgdir/usr/share/icons/hicolor/64x64/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-96x96.png \
+    "$pkgdir/usr/share/icons/hicolor/96x96/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-128x128.png \
+    "$pkgdir/usr/share/icons/hicolor/128x128/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-256x256.png \
+    "$pkgdir/usr/share/icons/hicolor/256x256/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser-512x512.png \
+    "$pkgdir/usr/share/icons/hicolor/512x512/apps/qutebrowser.png"
+  install -Dm644 icons/qutebrowser.svg \
+    "$pkgdir/usr/share/icons/hicolor/scalable/apps/qutebrowser.svg"
+}
diff --git a/pcr/qutebrowser-git/qutebrowser-git.install b/pcr/qutebrowser-git/qutebrowser-git.install
new file mode 100644
index 000000000..5c501dc49
--- /dev/null
+++ b/pcr/qutebrowser-git/qutebrowser-git.install
@@ -0,0 +1,12 @@
+post_install() {
+  xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+  update-desktop-database -q
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}
-- 
cgit v1.2.3-2-g168b