From 261b0259fc9d1652adf5276f1b2148ff6256b4ee Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Nicol=C3=A1s=20Reynolds?= <fauno@endefensadelsl.org>
Date: Wed, 15 Jan 2014 16:53:17 -0300
Subject: pspp: gnu statistical analysis

---
 pcr/pspp/PKGBUILD     | 34 ++++++++++++++++++++++++++++++++++
 pcr/pspp/pspp.install | 18 ++++++++++++++++++
 2 files changed, 52 insertions(+)
 create mode 100644 pcr/pspp/PKGBUILD
 create mode 100644 pcr/pspp/pspp.install

diff --git a/pcr/pspp/PKGBUILD b/pcr/pspp/PKGBUILD
new file mode 100644
index 000000000..d0042745f
--- /dev/null
+++ b/pcr/pspp/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer: Miguel Revilla <yo@miguelrevilla.com>
+# Contributor: joyfulgirl <joyfulgirl (at) archlinux.us>
+pkgname=pspp
+pkgver=0.8.2
+pkgrel=1
+pkgdesc="Statistical analysis program"
+arch=('i686' 'x86_64')
+url="http://www.gnu.org/software/pspp/"
+license=('GPL3')
+depends=('gsl' 'gtksourceview2' 'postgresql-libs' 'desktop-file-utils')
+optdepends=('zlib: GNUmeric support'
+            'libxml2: GNUMERIC support')
+options=('!libtool' '!emptydirs')
+source=(http://ftp.gnu.org/gnu/pspp/pspp-${pkgver}.tar.gz)
+md5sums=('cba0b161bb69e1bbd71612d09694b0ec')
+install=pspp.install
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    ./configure --prefix=/usr \
+                --sysconfdir=/etc \
+                --without-libreadline-prefix
+    make
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    make DESTDIR="${pkgdir}" install
+    rm -f "${pkgdir}/usr/share/info/dir"
+    install -d "${pkgdir}"/usr/share/pspp/contrib
+    install -m 644 pspp-mode.el "${pkgdir}"/usr/share/pspp/contrib/pspp-mode.el
+}
+
+# End of file
diff --git a/pcr/pspp/pspp.install b/pcr/pspp/pspp.install
new file mode 100644
index 000000000..def5ae5a5
--- /dev/null
+++ b/pcr/pspp/pspp.install
@@ -0,0 +1,18 @@
+post_install() {
+  update-desktop-database -q
+  gtk-update-icon-cache /usr/share/icons/hicolor
+  cd /usr/share/info
+  install-info pspp.info.gz dir
+  install-info pspp-dev.info dir
+}
+
+pre_remove() {
+  cd /usr/share/info
+  install-info --remove pspp.info.gz dir
+  install-info --remove pspp-dev.info dir
+}
+
+post_remove() {
+  update-desktop-database -q
+  gtk-update-icon-cache /usr/share/icons/hicolor
+}
-- 
cgit v1.2.3-2-g168b