1 files changed, 56 insertions, 0 deletions
diff --git a/pcr/kiwix-git/PKGBUILD b/pcr/kiwix-git/PKGBUILD
new file mode 100644
index 000000000..ea242122f
--- /dev/null
+++ b/pcr/kiwix-git/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer: André Silva <emulatorman@parabola.nu>
+
+_pkgname=kiwix
+pkgname=kiwix-git
+pkgver=r4591.785a7f1
+_gitver=785a7f156f4bf46b447f3a2ae8ba749fc3a5008a
+pkgrel=1
+pkgdesc="Offline reader for Web content. It's especially intended to make Wikipedia available offline"
+arch=('i686' 'x86_64' 'armv7h')
+url="http://www.kiwix.org/"
+license=('GPL3')
+depends=('rpcbind' 'gtk2' 'alsa-lib' 'libxt' 'libcanberra' 'sqlite3' 'java-environment')
+makedepends=('cmake' 'zip' 'xapian-core' 'icu' 'libmicrohttpd' 'zimlib' 'pugixml'
+             'ctpp2' 'aria2' 'bc' 'wget' 'xulrunner' 'git')
+conflicts=(kiwix-bin kiwix)
+install=kiwix.install
+source=(kiwix-$pkgver::git+https://github.com/kiwix/kiwix_mirror.git#commit=$_gitver
+        kiwix.desktop
+        0001-remove-static-makefile.patch
+        0002-fix-python2-path.patch
+        0003-fix-nspr-include-path.patch)
+sha256sums=('SKIP'
+            '3790697dc5d4c7c45c0f4b24e8c0d1129446c13e300bb60934eb8a743b9176c5'
+            '7dba1e10bd5cd49c771534a83c6591d22444edae21a719634876e99c943cc245'
+            '228385a1508b7a380b87717fbb877700b5ad0bad1e327a83e32f4bea2ee71824'
+            'd3696513bef5506bc397bfbd7870e259a3c88870b682b0052aed5c29b2fa5f75')
+pkgver() {
+  cd $_pkgname-$pkgver
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd $_pkgname-$pkgver
+  patch -Np1 -i ../0001-remove-static-makefile.patch
+  patch -Np1 -i ../0002-fix-python2-path.patch
+  patch -Np1 -i ../0003-fix-nspr-include-path.patch
+}
+
+build() {
+  cd $_pkgname-$pkgver
+  ./autogen.sh
+  ./configure --prefix=/usr \
+              --sysconfdir=/etc \
+              --enable-indexer \
+              --enable-installer \
+              --enable-manager \
+              --enable-server \
+              --enable-jar
+  make
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -D -m644 $srcdir/$_pkgname.desktop $pkgdir/usr/share/applications/$_pkgname.desktop
+}