1 files changed, 50 insertions, 0 deletions
diff --git a/libre/unp/PKGBUILD b/libre/unp/PKGBUILD
new file mode 100644
index 000000000..fe4b53c47
--- /dev/null
+++ b/libre/unp/PKGBUILD
@@ -0,0 +1,50 @@
+# $Id: PKGBUILD 116352 2014-07-25 17:05:00Z anatolik $
+# Maintainer (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
+# Contributor (Arch): Michael Düll <mail@akurei.me> PGP-Key: AAAEE882
+# Contributor (Arch): TDY <tdy@gmx.com>
+# Contributor (Arch): Sergio Rubio <rubiojr.ml@gmail.com>
+# Contributor (Arch): Hannes Rist <cowider@gmail.com>
+# Maintainer: André Silva <emulatorman@parabola.nu>
+ 
+pkgname=unp
+pkgver=2.0~pre7+nmu1
+pkgrel=2.parabola1
+pkgdesc='A script for unpacking a wide variety of archive formats, without nonfree unace, unarj and unrar recommendation'
+arch=(any)
+url='http://packages.qa.debian.org/u/unp.html'
+license=(GPL)
+depends=(perl)
+optdepends=(
+  'unzip: zip support'
+  'bzip2: bzip2 support'
+  'p7zip: p7zip support'
+  'cpio: cpio support'
+  'sharutils: sharutils'
+  'cabextract: cab support'
+  'rpmextract: rpm support'
+)
+source=(http://ftp.debian.org/debian/pool/main/u/unp/unp_$pkgver.tar.bz2
+        libre.patch)
+sha1sums=('b91f4cbc4720b3aace147652ac2043cf74668244'
+          '202375dd1c013c798d0d61ab5c273be8ebe1c546')
+
+prepare() {
+  cd unp-$pkgver
+  patch -Np1 -i "$srcdir"/libre.patch
+}
+
+build() {
+  cd unp-$pkgver/po
+  make
+}
+ 
+package() {
+  cd unp-$pkgver
+  install -Dm755 unp "$pkgdir"/usr/bin/unp
+  install -Dm755 ucat "$pkgdir"/usr/bin/ucat
+  install -Dm644 debian/unp.1 "$pkgdir"/usr/share/man/man1/unp.1
+  install -Dm755 bash_completion.d/unp "$pkgdir"/etc/bash_completion.d/unp.sh
+
+  cd po
+  make DESTDIR="$pkgdir" install
+}